home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / commodore-scene-files / Coverdisks / CDU / V1D4.D64 / basic editor (.txt) < prev    next >
Encoding:
Commodore BASIC  |  2019-04-13  |  9.8 KB  |  312 lines
  1. 10 REM ****************************
  2. 20 REM **  BASIC EDITOR  VER1.0  **
  3. 30 REM ** BY P.F.HAYES  (C) 1988 **
  4. 40 REM ****************************
  5. 50 PRINT"[147]INITIALISING PROGRAM":GOSUB 2900:CLR:GOSUB 1720
  6. 60 GOSUB 1770
  7. 70 PRINT"[147][158]**************BASIC EDITOR**************[154]"
  8. 80 PRINT"      1) EXIT FROM EDITOR"
  9. 90 PRINT"      2) RE-INITIALISE PROGRAM"
  10. 100 PRINT"      3) LOAD FILE"
  11. 110 PRINT"      4) INPUT LINE(S)"
  12. 120 PRINT"      5) LIST LINE(S)"
  13. 130 PRINT"      6) DELETE LINE(S)"
  14. 140 PRINT"      7) EDIT FILE"
  15. 150 PRINT"      8) MERGE/APPEND FILE"
  16. 160 PRINT"      9) SAVE FILE LINE(S)"
  17. 170 PRINT"     10) CHANGE DEVICE NUMBER"
  18. 180 PRINT"     11) SEARCH FOR STRING"
  19. 190 PRINT"     12) DIRECTORY"
  20. 200 INPUT"COMMAND (1-12) = ";CM
  21. 210 IF CM=1 THEN GOTO 2820
  22. 220 IF CM=2 OR CM=3 THEN INPUT"ERASES CURRENT FILE:CONTINUE (Y/N)   N[157][157][157]";T$
  23. 230 IF CM=2 AND T$="Y" THEN CLR:GOSUB 1720:GOSUB 1770
  24. 240 IF CM=3 AND T$="Y" THEN CLR:CM=3:GOSUB 1720:GOSUB 1770:GOSUB 1360
  25. 250 IF CM>3 THEN ON CM-3 GOSUB 280,830,1130,1850,1280,1480,1680,2510,2680
  26. 260 GOTO 70
  27. 270 REM ***INPUT BASIC LINE(S)***
  28. 280 INPUT"AUTO LINE NUMBERING (Y/N)   N[157][157][157]";T$
  29. 290 IF T$="Y" THEN 400
  30. 300 PRINT"[147]":OPEN 2,0
  31. 310 INPUT@2,IP$:IF IP$=CHR$(95) THEN 370
  32. 320 IF LEN(IP$)>80 THEN IP$=LEFT$(IP$,80)
  33. 330 GOSUB 500:IF LN=-1 THEN 370
  34. 340 IF LN<1 OR LN>65534 THEN PRINT"INVALID LINE NUMBER:RE-ENTER":GOTO 310
  35. 350 GOSUB 550:IF LEN(IP$)=0 THEN 380
  36. 360 GOSUB 580:IF NOT ERR THEN PRINT:GOTO 310
  37. 370 CLOSE 2:RETURN
  38. 380 GOSUB 750:IF NOT ERR THEN GOSUB 1190
  39. 390 PRINT:GOTO 310
  40. 400 INPUT"START LINE NUMBER = ";BL:INPUT"LINE NUMBER INCREMENT = ";IL
  41. 410 PRINT"[147]":OPEN 2,0:SI=0
  42. 420 AL$=MID$(STR$(BL+SI),2):PRINTAL$;" ";:INPUT@2,IP$:IF IP$=CHR$(95) THEN 480
  43. 430 IP$=AL$+IP$:IF LEN(IP$)>80 THEN IP$=LEFT$(IP$,80)
  44. 440 GOSUB 500:IF LN=-1 THEN 480
  45. 450 IF LN<1 OR LN>65534 THEN PRINT"INVALID LINE NUMBER:RE-ENTER":GOTO 420
  46. 460 GOSUB 550:IF LEN(IP$)=0 THEN PRINT:GOTO 420
  47. 470 GOSUB 580:IF NOT ERR THEN SI=SI+IL:PRINT:GOTO 420
  48. 480 CLOSE 2:RETURN
  49. 490 REM ***EXTRACT LINE NUMBER***
  50. 500 LN=-1:IF LEN(IP$)=0 OR IP$<"0" OR LEFT$(IP$,1)>"9" THEN 530
  51. 510 FOR T=1 TO LEN(IP$):IF MID$(IP$,T,1)<="9" AND MID$(IP$,T,1)>="0" THEN NEXT T
  52. 520 LN=VAL(LEFT$(IP$,T-1)):IP$=MID$(IP$,T)
  53. 530 RETURN
  54. 540 REM ***EXTRACT LINE TEXT***
  55. 550 FOR T=1 TO LEN(IP$):IF MID$(IP$,T,1)=" " THEN NEXT T
  56. 560 IP$=MID$(IP$,T):RETURN
  57. 570 REM ***INSERT LINE IN FILE ARRAY***
  58. 580 IF LN<1 OR LN>65534 THEN 720
  59. 590 GOSUB 750
  60. 600 TT=IM
  61. 610 IF NOT ERR THEN TT=MA:GOTO 660
  62. 620 IF LEN(EM$)=0 THEN 640
  63. 630 TT=FNE1(TT):EM$=MID$(EM$,3):IM=IM-1:VA=VA-1
  64. 640 KK$=CHR$(TT/256)+CHR$(TT-256*INT(TT/256))
  65. 650 MR$(QQ)=LEFT$(MR$(QQ),2*LM-2)+KK$+MID$(MR$(QQ),2*LM-1)
  66. 660 T1=FNE2(LN):A$(TT)=CHR$(LN-T1*256)+CHR$(T1)+IP$
  67. 670 IF NOT ERR THEN 730
  68. 680 FOR I=0 TO 6:IF LEN(MR$(I))<=250 THEN 710
  69. 690 MR$(I+1)=RIGHT$(MR$(I),2)+MR$(I+1)
  70. 700 MR$(I)=LEFT$(MR$(I),LEN(MR$(I))-2):IF PEEK(152)<>0 THEN T=FRE(0)
  71. 710 NEXT I:IM=IM+1
  72. 720 ERR=FALSE
  73. 730 RETURN
  74. 740 REM ***FIND LINE NUMBER IN FILE ARRAY***
  75. 750 TT=IM-VA:PW=FNF5(TT):MM=FNF6(PW):FOR BV=PW-1 TO 0 STEP -1
  76. 760 QQ=FNF1(MM):LM=FNF2(MM):MA=FNF3(QQ):T1=FNF4(MA):MM=FNF7(MM)
  77. 770 IF MM>TT-1 THEN MM=TT-1
  78. 780 NEXT BV
  79. 790 QQ=FNF1(MM):LM=FNF2(MM):MA=FNF3(QQ):T1=FNF4(MA):IF T1>=LN THEN 810
  80. 800 MM=MM+1:GOTO 790
  81. 810 ERR=NOT(T1=LN):RETURN
  82. 820 REM ***LIST LINES***
  83. 830 GOSUB 930:IF ERR THEN 910
  84. 840 GOTO 2820
  85. 850 PRINT"[147]":GOSUB 1040:IF FM<SM OR FM=0 THEN 910
  86. 860 IF DEV=4 THEN OPEN 2,DEV:CMD 2
  87. 870 FOR MM=SM TO FM:QQ=FNF1(MM):LM=FNF2(MM):MA=FNF3(QQ):GOSUB 1090:NEXT MM
  88. 880 IF DEV=4 THEN PRINT#2:CLOSE 2:GOSUB 1680
  89. 890 IF PEEK(152)=0 THEN PRINT"< RETURN FOR MAIN MENU >"
  90. 900 IF PEEK(152)=0 THEN GETT$:IF T$="" THEN 900
  91. 910 RETURN
  92. 920 REM ***INPUT LINE NUMBER RANGE***
  93. 930 PRINT"ENTER LINE NUMBER RANGE (EG 100-500)"
  94. 940 IP$="":INPUT"FIRST LINE-LAST LINE = ";IP$
  95. 950 SL=1:FL=65534:ERR=FALSE
  96. 960 IF LEN(IP$)=0 THEN 1020
  97. 970 GOSUB 500:IF LN>=0 THEN SL=LN:GOTO 990
  98. 980 IF LN>-1 THEN FL=-LN:GOTO 1020
  99. 990 GOSUB 550:IF LEN(IP$)=0 THEN FL=SL:GOTO 1020
  100. 1000 IP$=MID$(IP$,2):GOSUB 550
  101. 1010 IF LEN(IP$)>0 THEN GOSUB 500:FL=LN
  102. 1020 ERR=SL<1 OR SL>65534 OR FL<1 OR FL>65534 OR ERR:RETURN
  103. 1030 REM ***LINE NUMBER RANGE MARKERS***
  104. 1040 LN=SL:GOSUB 750:SM=MM
  105. 1050 LN=FL:GOSUB 750:FM=MM
  106. 1060 IF ERR THEN FM=FM-1
  107. 1070 RETURN
  108. 1080 REM ***LIST LINES MARKED BY MA***
  109. 1090 TP$=STR$(FNF4(MA)):PRINTMID$(TP$,2);" ";MID$(A$(MA),3)
  110. 1100 IF PEEK(152)=0 THEN WAIT 198,1,1:POKE 198,0
  111. 1110 RETURN
  112. 1120 REM ***DELETE LINE(S)***
  113. 1130 GOSUB 930:IF ERR THEN 1170
  114. 1140 GOTO 2820
  115. 1150 GOSUB 1040:IF FM<SM THEN 1170
  116. 1160 FOR MM=FMTOSM STEP -1:QQ=FNF1(MM):LM=FNF2(MM):MA=FNF3(QQ):GOSUB 1190:NEXTMM
  117. 1170 RETURN
  118. 1180 REM ***DELETE LINE MARKED BY MA***
  119. 1190 MR$(QQ)=LEFT$(MR$(QQ),2*LM-2)+MID$(MR$(QQ),2*LM+1)
  120. 1200 FOR I=0 TO 6
  121. 1210 IF LEN(MR$(I))>=250 OR LEN(MR$(I+1))=0 THEN 1230
  122. 1220 MR$(I)=MR$(I)+LEFT$(MR$(I+1),2):MR$(I+1)=MID$(MR$(I+1),3)
  123. 1230 NEXT I:VA=VA+1:A$(MA)=""
  124. 1240 IF LEN(EM$)>250 THEN 1260
  125. 1250 EM$=CHR$(MA/256)+CHR$(MA-256*INT(MA/256))+EM$
  126. 1260 RETURN
  127. 1270 REM ***MERGE FILE FROM DEVICE***
  128. 1280 GOSUB 1630:IF DEV=8 THEN TN$=TN$+",S,R"
  129. 1290 IF DEV<>1 AND DEV<>8 THEN RETURN
  130. 1300 GOTO 2820
  131. 1310 OPEN 2,DEV,0,TN$
  132. 1320 INPUT@2,IP$:GOSUB 500:IF LN=-1 OR ST THEN 1340
  133. 1330 GOSUB 550:GOSUB 580:GOTO 1320
  134. 1340 CLOSE 2:RETURN
  135. 1350 REM ***LOAD FILE FROM DEVICE***
  136. 1360 GOSUB 1630:IF DEV=8 THEN TN$=TN$+",S,R"
  137. 1370 IF DEV<>1 AND DEV<>8 THEN RETURN
  138. 1380 GOTO 2820
  139. 1390 OPEN 2,DEV,0,TN$
  140. 1400 INPUT@2,IP$:GOSUB 500:IF LN=-1 OR ST THEN 1460
  141. 1410 GOSUB 550:GOSUB 580
  142. 1420 INPUT@2,IP$:GOSUB 500:IF LN=-1 OR ST THEN 1460
  143. 1430 GOSUB 550:MM=MM+1:QQ=FNF1(MM):LM=FNF2(MM)
  144. 1440 IF LN<1 OR LN>65534 THEN 1420
  145. 1450 ERR=-1:GOSUB 600:GOTO 1420
  146. 1460 CLOSE 2:RETURN
  147. 1470 REM ***SAVE FILE TO DEVICE***
  148. 1480 GOSUB 1630:GOSUB 930:IF DEV<>1 AND DEV<>8 THEN 1610
  149. 1490 IF ERR THEN PRINT"INVALID LINES:RE-ENTER COMMANDS":GOTO 1480
  150. 1500 GOSUB 1040:ERR=(FL<SL):IF ERR THEN GOTO 1490
  151. 1510 IF DEV<>8 THEN 1580
  152. 1520 PRINT"ENTER FILE OPERATION :"
  153. 1530 INPUT"C[146]REATE,O[146]VERWRITE,A[146]PPEND (C/O/A) ";T$
  154. 1540 IF T$="C" THEN TN$=TN$+",S,W":GOTO 1580
  155. 1550 IF T$="O" THEN TN$="@0:"+TN$+",S,W":GOTO 1580
  156. 1560 IF T$="A" THEN TN$=TN$+",S,A":GOTO 1580
  157. 1570 GOTO 1510
  158. 1580 GOTO 2820
  159. 1590 OPEN 2,DEV,2,TN$:CMD 2:GOSUB 870
  160. 1600 PRINT#2:CLOSE 2
  161. 1610 RETURN
  162. 1620 REM ***INPUT FILE NAME***
  163. 1630 TN$="":GOSUB 1680:IF DEV=4 THEN 1660
  164. 1640 INPUT"FILE NAME = ";TN$:LT=LEN(TN$)
  165. 1650 IF LT>16 OR LT<1 THEN PRINT"FILE NAME INVALID":GOTO 1640
  166. 1660 RETURN
  167. 1670 REM ***CHANGE DEVICE NUMBER***
  168. 1680 PRINT"(PRINTER=4:DISC=8:TAPE=1)"
  169. 1690 PRINT SPC(21) DEV
  170. 1700 INPUT"[145]NEW DEVICE NUMBER = ";DEV:RETURN
  171. 1710 REM ***INITIALISE PROGRAM & DEFINE FUNCTIONS***
  172. 1720 DIM MR$(7),A$(300),FS(50):IM=2:VA=0
  173. 1730 MR$(0)=CHR$(0)+CHR$(0)+CHR$(0)+CHR$(1)
  174. 1740 A$(0)=CHR$(0)+CHR$(0):A$(1)=CHR$(255)+CHR$(255)
  175. 1750 CP$=""
  176. 1760 O$="                                        ":O$=O$+O$:RETURN
  177. 1770 DEF FNF1(MM)=INT((MM-1)/125):DEF FNF2(MM)=MM-125*QQ
  178. 1780 DEF FNF3(QQ)=256*ASC(MID$(MR$(QQ),2*LM-1))+ASC(MID$(MR$(QQ),2*LM))
  179. 1790 DEF FNF4(MA)=ASC(MID$(A$(MA),1,1))+256*ASC(MID$(A$(MA),2,1))
  180. 1800 DEF FNF5(TT)=INT(LOG(TT)/.693147)
  181. 1810 DEF FNF6(PW)=2^PW:DEF FNF7(MM)=MM+2^BV*((LN<T1)-(LN>T1))
  182. 1820 DEF FNF8(P)=1024+LR*40+P:DEF FNE1(TT)=256*ASC(EM$)+ASC(MID$(EM$,2))
  183. 1830 DEF FNE2(LN)=INT(LN/256):RETURN
  184. 1840 REM ***EDIT FILE***
  185. 1850 P=0:LR=1:LP=1:AI=0:TF=0:NS=11:TP$="":FQ=0:IF TH=1 THEN TH=0:GOTO 1930
  186. 1860 IF TC=1 THEN TC=0:GOTO 1930
  187. 1870 INPUT"EDIT FROM LINENUMBER = ";LN:LT=LN
  188. 1880 GOSUB 750:IF ERR AND TF=0 OR LN<1 OR LN>65534 THEN 1900
  189. 1890 GOTO 1930
  190. 1900 INPUT"INVALID LINE:R[146]E-ENTER OR E[146]XIT";T$
  191. 1910 IF T$="E" THEN RETURN
  192. 1920 GOTO 1870
  193. 1930 IF NS>IM-MM-VA THEN NS=IM-MM-VA
  194. 1940 IF NS=0 AND (IM-VA)>2 THEN 2420
  195. 1950 IF NS=0 THEN RETURN
  196. 1960 PT=MM:QQ=FNF1(MM):LM=FNF2(MM):MA=FNF3(QQ):LT=VAL(STR$(FNF4(MA))):PRINT"[147]"
  197. 1970 FOR PR=1 TO NS
  198. 1980 QQ=FNF1(MM):LM=FNF2(MM):MA=FNF3(QQ)
  199. 1990 TP$=STR$(FNF4(MA))
  200. 2000 TP$=MID$(TP$,2)+" "+MID$(A$(MA),3)
  201. 2010 CD$=LEFT$(CP$,LR-(2*INT(LR/2)-LR<>0)-1)
  202. 2020 PRINT"";CD$;O$;"[145][145]";TP$
  203. 2030 MM=MM+1:LR=LR+2:NEXT PR
  204. 2040 LR=LP+2*(LP=NS*2+1)
  205. 2050 AC=AI:AI=PT+INT((LR+1)/2)-1:IF AI=AC AND TF=0 THEN 2090
  206. 2060 QQ=INT((AI-1)/125):LM=AI-125*QQ:TF=0
  207. 2070 MA=FNF3(QQ):TP$=STR$(FNF4(MA))
  208. 2080 TP$=MID$(TP$,2)+" "+MID$(A$(MA),3)
  209. 2090 CD$=LEFT$(CP$,LR-(2*INT(LR/2)-LR<>0)-1)
  210. 2100 PRINT"";CD$;O$;"[145][145]";TP$
  211. 2110 CH=PEEK(FNF8(P)):POKE 54272+FNF8(P),14:POKE FNF8(P),160
  212. 2120 FOR NU=1 TO 5:NEXT NU:POKE FNF8(P),CH
  213. 2130 GET SC$:IF SC$="" THEN 2110
  214. 2140 IF SC$=CHR$(34) THEN FQ=-(FQ=0)
  215. 2150 IF SC$=CHR$(13) THEN 2440
  216. 2160 IF SC$=CHR$(141) THEN RETURN
  217. 2170 IF SC$=CHR$(19) AND FQ=0 THEN RETURN
  218. 2180 IF SC$=CHR$(147) AND FQ=0 THEN RETURN
  219. 2190 IF SC$=CHR$(133) THEN 2400
  220. 2200 IF SC$=CHR$(137) THEN 2420
  221. 2210 IF SC$=CHR$(134) THEN P=0:LR=1:GOTO 2050
  222. 2220 IF SC$=CHR$(138) THEN P=0:LR=NS*2-1:GOTO 2050
  223. 2230 IF SC$=CHR$(135) THEN P=0:GOTO 2110
  224. 2240 IF SC$=CHR$(139) THEN P=LEN(TP$)-1:GOTO 2110
  225. 2250 IF SC$=CHR$(136) THEN RETURN
  226. 2260 IF SC$=CHR$(140) THEN PRINT"[147]":GOTO 1850
  227. 2270 IF P>0 AND SC$=CHR$(20) THEN TP$=LEFT$(TP$,P-1)+MID$(TP$,P+1):P=P-1
  228. 2280 IF SC$=CHR$(20) THEN 2050
  229. 2290 IF SC$="[145]" AND P<=39 AND FQ=0 THEN LR=LR+2*(LR>1):P=0:GOTO 2050
  230. 2300 IF SC$="[145]" AND P>39 AND FQ=0 THEN P=P-40:GOTO 2110
  231. 2310 IF SC$="" AND P<=39 AND LEN(TP$)>40 AND FQ=0 THEN P=40:GOTO 2110
  232. 2320 IF SC$="" AND FQ=0 THEN LR=LR-2*(LR<NS*2-1):P=0:GOTO 2050
  233. 2330 IF LEN(TP$)=80 THEN 2370
  234. 2340 IF SC$=CHR$(148) THEN TP$=LEFT$(TP$,P)+" "+MID$(TP$,P+1):GOTO 2050
  235. 2350 IF FQ=1 THEN TP$=LEFT$(TP$,P)+SC$+MID$(TP$,P+2):P=P-1*(P<79):GOTO 2050
  236. 2360 IFSC$<>"[157]"ANDSC$<>""THENTP$=LEFT$(TP$,P)+SC$+MID$(TP$,P+2):P=P-1*(P<79):GOTO2050
  237. 2370 IF SC$="[157]" AND P>0 THEN P=P-1
  238. 2380 IF SC$="" AND P<LEN(TP$)-1 THEN P=P+1
  239. 2390 GOTO 2110
  240. 2400 MM=PT+11:IF MM>IM-VA THEN MM=IM-VA-1
  241. 2410 TH=1:GOTO 1850
  242. 2420 MM=PT-11:IF MM<2 THEN MM=2
  243. 2430 TC=1:GOTO 1850
  244. 2440 IP$=LEFT$(TP$,LEN(TP$))
  245. 2450 GOSUB 500:IF LN<1 OR LN>65534 OR LN=-1 THEN 2490
  246. 2460 GOSUB 550:IF LEN(IP$)=0 THEN 2480
  247. 2470 GOSUB 580:GOTO 2490
  248. 2480 GOSUB 750:IF NOT ERR THEN GOSUB 1190
  249. 2490 TF=1:P=0:LP=LR:LN=LT:LR=1:NS=11:FQ=0:GOTO 1880
  250. 2500 REM ***SEARCH ROUTINE***
  251. 2510 INPUT"INPUT SEARCH STRING = ";TG$:GOSUB 930:IF ERR THEN RETURN
  252. 2520 GOSUB 1040:IF FM<SM OR FM=0 THEN RETURN
  253. 2530 GOTO 2820
  254. 2540 PRINT"[147]LINES FOUND=    LINES SCANNED="
  255. 2550 K=0:FOR MM=SM TO FM:QQ=FNF1(MM):LM=FNF2(MM):MA=FNF3(QQ)
  256. 2560 FOR I=1 TO LEN(A$(MA))-LEN(TG$)+1
  257. 2570 IF MID$(A$(MA),I,LEN(TG$))=TG$ THEN K=K+1:FS(K)=MA:GOTO 2590
  258. 2580 NEXT I
  259. 2590 IF K>49 THEN PRINT"SEARCH TERMINATING-ARRAY FS(K) FULL":GOTO 2620
  260. 2600 PRINT"";K;"";MM-SM+1:NEXT MM:PRINT
  261. 2610 REM ***LIST SEARCH LINES***
  262. 2620 IF K=0 THEN 2660
  263. 2630 FOR I=1TOK:MA=FS(I):TP$=STR$(FNF4(MA)):PRINTMID$(TP$,2);" ";MID$(A$(MA),3)
  264. 2640 IF PEEK(152)=0 THEN WAIT 198,1,1:POKE 198,0
  265. 2650 NEXT I
  266. 2660 GOTO 890
  267. 2670 REM ***LIST DIRECTORY***
  268. 2680 PRINT"[147]":OPEN 1,8,0,"$0":GET#1,B$,D$
  269. 2690 GET#1,B$,D$:GET#1,B$,D$:B=0
  270. 2700 IF B$<>"" THEN B=ASC(B$)
  271. 2710 IF D$<>"" THEN B=B+ASC(D$)*256
  272. 2720 PRINT""MID$(STR$(B),2);TAB(5);"[146]";
  273. 2730 GET#1,D$:IF ST<>0 THEN 2810
  274. 2740 IF D$<>CHR$(34) THEN 2730
  275. 2750 GET#1,D$:IF D$ <>CHR$(34) THEN PRINTD$;:GOTO 2750
  276. 2760 GET#1,D$:IF D$=CHR$(32) THEN 2760
  277. 2770 PRINT TAB(18);:C$=""
  278. 2780 C$=C$+D$:GET#1,D$:IF D$<>"" THEN 2780
  279. 2790 PRINTTAB(22)""LEFT$(C$,3)
  280. 2800 IF ST=0 THEN 2690
  281. 2810 PRINT"BLOCKS FREE":CLOSE 1:GOTO 890
  282. 2820 REM ***CONFIRMATION ROUTINE***
  283. 2830 INPUT"IS ABOVE CORRECT (Y/N)  Y[157][157][157]";T$
  284. 2840 IFT$="Y"THEN ONCMGOTO 2870,2870,1390,2870,850,1150,2870,1310,1590,2870,2540
  285. 2850 IFT$="N"THEN ONCMGOTO 70,70,2880,2880,2880,2880,2880,2880,2880,2880,2880
  286. 2860 GOTO 2830
  287. 2870 CLR:END
  288. 2880 RETURN
  289. 2890 REM ***INPUT@ ROUTINE***
  290. 2900 AD=49152:LN=2960
  291. 2910 READ VL:IF VL<256 THEN POKE AD,VL:SU=SU+VL:AD=AD+1:GOTO 2910
  292. 2920 IF SU=VL THEN SU=0:LN=LN+10:GOTO 2910
  293. 2930 IF VL=999 THEN 2950
  294. 2940 PRINT"[147]DATA ERROR IN LINE";LN:STOP
  295. 2950 SYS 49152:RETURN
  296. 2960 DATA 169,11,160,192,141,8,3,140,824
  297. 2970 DATA 9,3,96,32,115,0,201,133,589
  298. 2980 DATA 240,6,32,121,0,76,231,167,873
  299. 2990 DATA 32,115,0,201,64,240,6,32,690
  300. 3000 DATA 191,171,76,174,167,32,155,183,1149
  301. 3010 DATA 32,30,225,32,253,174,160,0,906
  302. 3020 DATA 32,183,255,41,100,208,20,132,971
  303. 3030 DATA 252,32,18,225,164,252,153,160,1256
  304. 3040 DATA 192,200,201,13,208,234,136,192,1376
  305. 3050 DATA 0,240,227,132,251,32,139,176,1197
  306. 3060 DATA 133,73,132,74,32,163,182,165,954
  307. 3070 DATA 251,32,117,180,160,2,185,97,1024
  308. 3080 DATA 0,145,73,136,16,248,164,251,1033
  309. 3090 DATA 192,0,240,9,136,185,160,192,1114
  310. 3100 DATA 145,98,136,16,248,32,204,255,1134
  311. 3110 DATA 76,174,167,417,999
  312.